Mikrotik cihazınızın konfigurasyonunu belirli aralıklarla ftp sunucusuna yedeklemek isterseniz kullanabileceğiniz güzel bir script aşağıda yer almaktadır.
bunu system schedule içerisinde belirleyeceğiniz zamanlamaya göre çalıştırıp ftp sunucunuzda konfigurasyon yedeğinizi aşağıdaki parametreler doğrultusunda saklayabilirsiniz.

saveUserDB Usermanager Database’i yedeklensinmi ( true/false )
saveSysBackup Sistem Yedeği Alınsınmı ( true/false )
encryptSysBackup Sistem Yedeği Şifreli olarakmı alınsın( true/false )
saveRawExport Sistem Yedeği Export olarak alınsınmı ( true/false )

true = Evet
False = Hayır

FTPServer Ftp Sunucu Adı
FTPPort Ftp Sunucu Portu
FTPUser FTP Kullanıcı adı
FTPPass FTP Şifresi

:local saveUserDB false 
:local saveSysBackup true
:local encryptSysBackup false
:local saveRawExport true

:local FTPServer "FtpServerIPyadaDomain"
:local FTPPort 21 
:local FTPUser "FtpKullanıcıadı "
:local FTPPass "Şifre"


:local ts [/system clock get time]
:set ts ([:pick $ts 0 2].[:pick $ts 3 5].[:pick $ts 6 8])
:local ds [/system clock get date]
:set ds ([:pick $ds 7 11].[:pick $ds 0 3].[:pick $ds 4 6])

:local fname ("BACKUP-".[/system identity get name]."-".$ds."-".$ts)
:local sfname ("/".$fname)
:if ($saveUserDB) do={
  /tool user-manager database save name=($sfname.".umb")
  :log info message="User Manager Veritabanı Yedeklemesi Tamamlandı "
}
:if ($saveSysBackup) do={
  :if ($encryptSysBackup = true) do={ /system backup save name=($sfname.".backup") }
  :if ($encryptSysBackup = false) do={ /system backup save dont-encrypt=yes name=($sfname.".backup") }
  :log info message="System Yedeği Tamamlandı"
}
if ($saveRawExport) do={
  /export file=($sfname.".rsc")
  :log info message="Konfigurasyon Export Dosyası oluşturuldu. "
}
:local backupFileName ""
:foreach backupFile in=[/file find] do={
  :set backupFileName ("/".[/file get $backupFile name])
  :if ([:typeof [:find $backupFileName $sfname]] != "nil") do={
    /tool fetch address=$FTPServer port=$FTPPort src-path=$backupFileName user=$FTPUser mode=ftp password=$FTPPass dst-path=$backupFileName upload=yes
  }
}
:delay 5s
:foreach backupFile in=[/file find] do={
  :if ([:typeof [:find [/file get $backupFile name] "BACKUP-"]]!="nil") do={
    /file remove $backupFile
  }
}

:log info message="Gecici Dosyalar Silindi"
:log info message="Otomatik Yedekleme Tamamlandı."